魔兽世界12.0.5奶德宏命令分享

魔兽世界12.0.5版本已经上线一段时间了，因为大版本取消了很多插件，因此使用宏成了方便快捷的提高手法的手段，那么魔兽世界12.0.5奶德宏命令有哪些？下面就给大家带来魔兽世界12.0.5奶德宏命令分享。

魔兽世界12.0.5奶德宏命令分享

#showtooltip [@mouseover,help,nodead] [help,nodead] [noexists] 愈合; 月火术

/cast [@mouseover,help,nodead] 愈合; [@mouseover,harm,nodead] 月火术; [help,nodead] 愈合; 月火术

PS：鼠标在队友框架会读愈合，选定敌人为月火术。(哪怕目标是敌人优先按鼠标指向来使用愈合)

#showtooltip [@mouseover,help,nodead] [help,nodead] [noexists] 回春术; 阳炎术

/cast [@mouseover,help,nodead] 回春术; [@mouseover,harm,nodead] 阳炎术; [help,nodead] 回春术; 阳炎术

PS：鼠标在队友框架回春，选定敌人为阳炎术。(哪怕目标是敌人优先按鼠标指向来使用回春术)

#showtooltip 乌索尔旋风

/castsequence [nochanneling] reset=combat/target 魔力探测石,台风

/cast [nochanneling,@cursor] 乌索尔旋风

PS：乌吹，中间的魔力探测石自己去搞一个写宏里就好，过程十来分钟搞定。

#showtooltip [combat]影遁;潜行

/cancelform [combat,form]

/cast [combat]影遁;潜行

PS：隐遁潜行宏，战斗中隐遁，非战斗中为猎豹形态的潜行。

/cast [target=player] 激活

PS：没啥好介绍的，激活宏。

#showtooltip 生命绽放

/cast [@mouseover,exists,helpful,nodead] 生命绽放; [@player] 生命绽放

PS：鼠标指向生命绽放宏。

#showtooltip 狂暴回复

/cast [stance:1] 狂暴回复; [nostance:1] 熊形态

/script UIErrorsFrame:Clear()

PS：点一下变熊，在点一下狂暴回复，奶妈直接省下一个变熊的技能栏位，因为点一下变熊，在点一下才是狂暴回复，所以也不会存在误触，反正我用的时候一直没有过，而且在狂暴回复CD期间，这个宏正常显示狂暴回复的CD，且不会影响变形熊。

#showtooltip 自然之愈

/cast [@mouseover,exists] 自然之愈

PS：：鼠标指向驱散，指向框架也能用。

#showtooltip [@mouseover,help,nodead] [help,nodead] [noexists] 自然迅捷; 愤怒

/cast [@mouseover,help,nodead] 自然迅捷; [@mouseover,harm,nodead] 愤怒; [help,nodead] 自然迅捷; 愤怒

PS：自然迅捷愤怒宏，没有目标或者鼠标指向队友为自然迅捷，目标是敌人是愤怒。(哪怕目标是敌人优先按鼠标指向来使用自然迅捷)

#showtooltip [@mouseover,help,nodead] [help,nodead] [noexists] 迅捷治愈; 星涌术

/cast [@mouseover,help,nodead] 迅捷治愈; [@mouseover,harm,nodead] 星涌术; [help,nodead] 迅捷治愈; 星涌术

PS：目标是敌人为星涌术，没有目标或者鼠标指向队友为迅捷治愈(哪怕目标是敌人优先按鼠标指向来使用迅捷治愈)

#showtooltip

/cast [@mouseover,help,nodead] 野性成长;[help,nodead] 野性成长; [@player] 野性成长

PS：鼠标指向队友或者队友框架对其释放野性成长，否则默认对自己使用野性成长。

#showtooltip

/cast [@mouseover,help,nodead][] 铁木树皮

PS：铁木树皮指向宏。

#showtooltip 共生关系

/cast [@mouseover,help,nodead] 共生关系; [help,nodead] 共生关系

PS：鼠标指向共生关系宏。

#showtooltip [@mouseover,help,nodead] [help,nodead] [noexists] 愈合; 斜掠

/cast [@mouseover,help,nodead] 愈合; [@mouseover,harm,nodead] 斜掠; [help,nodead] 愈合; 斜掠

PS：：愈合;斜掠宏。(哪怕目标是敌人优先按鼠标指向来使用愈合)

#showtooltip [@mouseover,help,nodead] [help,nodead] [noexists] 回春术; 割裂

/cast [@mouseover,help,nodead] 回春术; [@mouseover,harm,nodead] 割裂; [help,nodead] 回春术; 割裂

PS：回春术;割裂宏。(哪怕目标是敌人优先按鼠标指向来使用割裂)

#showtooltip 复生

/cast [@focus,exists,dead] 复生; [@party1,dead] 复生; [@party2,dead] 复生; [@party3,dead] 复生; [@party4,dead] 复生; [@party5,dead] 复生

PS：随机战复宏，适合底层。

#showtooltip

/stopcasting

/use [@mouseover,help,nodead] 自然之愈

/use [@mouseover,help,dead,combat] 复生

/use [@mouseover,harm] 安抚

/use [@target,help,nodead] 自然之愈

/use [@target,help,dead,combat] 复生

/use [@target,harm] 安抚

/use 自然之愈

PS:友方存活：图标 = 自然之愈，施放自然之愈,鼠标指向友方死亡 + 战斗中：图标 = 复生，施放战复,鼠标指向敌人：图标 = 安抚，施放安抚,无鼠标指向时，按当前目标自动切换图标和技能,脱战死亡目标不会触发战复。

#showtooltips

/castsequence reset=1/combat 枭兽形态, 野性之心

PS：枭兽形态;野兽之心序列宏，按一下是枭兽形态，在1.5秒内在按就是枭兽形态的序列宏，然后过1.5秒该宏就会自动重置为枭兽形态的正常使用,主要是卡秒用,因为枭兽形态下的野兽之心哪怕变成变成人形态,枭兽形态的野兽之心还是不会打断技能的释放。

#showtooltip [@mouseover,help,exists]回春术;[harm]回旋急冲(驭空术);回旋急冲(驭空术)

/cast [@mouseover,help,exists]回春术;[@mouseover,harm,exists]回旋急冲(驭空术);[help]回春术;回旋急冲(驭空术)

PS：主要是在旅行形态可以使用回春术。且不会影响驭龙术。(在飞行形态下，如果有目标该宏会失效，不过飞行形态自己心里有个预估ESC取消目标就好了)

#showtooltip [@mouseover,help,exists]愈合;[harm]向前突进;向前突进

/cast [@mouseover,help,exists]愈合;[@mouseover,harm,exists]向前突进;[help]愈合;向前突进

PS：主要是在旅行形态可以使用愈合。且不会影响驭龙术。(在飞行形态下，如果有目标该宏会失效，不过飞行形态自己心里有个预估ESC取消目标就好了)

#showtooltip [@mouseover,help,exists]生命绽放;[harm]复苏之风;复苏之风

/cast [@mouseover,help,exists]生命绽放;[@mouseover,harm,exists]复苏之风;[help]生命绽放;复苏之风

PS：主要是在旅行形态可以使用生命缤放。且不会影响驭龙术。(在飞行形态下，如果有目标该宏会失效，不过飞行形态自己心里有个预估ESC取消目标就好了)

本文内容来源于互联网，如有侵权请联系删除。